BLOCK NUMBER 9

( CF83 Double Number Extension Word Set - Load Block )          
( Copyright [ c ] 1991 by BDS Software )                        
decimal                                                         
cr cr .( Loading Double Number Extension Word Set ) cr cr       
10 load .(    Loading Block 1 of 3 ) cr                         
11 load .(    Loading Block 2 of 3 ) cr                         
12 load .(    Loading Block 3 of 3 ) cr cr                      
.( Double Number Extension Word Set Loaded )                    
                                                                
                                                                
                                                                
                                                                
                                                                
                                                                
                                                                
                                                                

BLOCK NUMBER 10

( CF83 Double Number Extension Word Set - 1/3 )                 
( Copyright [ c ] 1991 by BDS Software )                        
16 base !                                                       
: 2! ( 32b addr -- ) 2+ swap over 2- ! ! ;                      
: 2@ ( addr -- 32b ) dup 2+ @ swap @ ;                          
: 2constant ( 32b -- ) create , , does> dup @ swap 2+ @ swap ;  
: 2drop ( 32b -- ) drop drop ;                                  
: 2dup ( 32b -- 32b 32b ) over over ;                           
: 2over ( 32b1 32b2 -- 32b1 32b2 32b3 ) 3 pick 3 pick ;         
: 2rot ( 32b1 32b2 32b3 -- 32b2 32b3 32b1 ) 5 roll 5 roll ;     
: 2swap ( 32b1 32b2 -- 32b2 32b1 ) 3 roll 3 roll ;              
: 2variable ( -- ) create 0 , 0 , ;                             
: d- ( wd1 wd2 -- wd3 ) dnegate d+ ;                            
: dabs ( d -- ud ) 2dup 0 0 d< if dnegate then ;                
decimal                                                         
                                                                

BLOCK NUMBER 11

( CF83 Double Number Extension Word Set - 2/3 )                 
( Copyright [ c ] 1991 by BDS Software )                        
16 base !                                                       
: d>ns ( d -- addr +n ) swap over dabs <# #s rot sign #> ;      
: d. ( d -- ) d>ns type space ;                                 
: d.r ( d +n -- ) >r d>ns r> over - spaces type ;               
: d0= ( d -- flag ) or 0= ;                                     
create d2/ ( d1 -- d2 ) here dup 2- ! 3416 , 3706 , 4756 ,      
     1F01 , 3706 , 4656 , 3606 , 1F10 , 3606 , 3516 ,           
     AEA1 , 6E91 ,                                              
: d= ( d1 d2 -- flag ) d- d0= ;                                 
decimal                                                         
                                                                
                                                                
                                                                
                                                                

BLOCK NUMBER 12

( CF83 Double Number Extension Word Set - 3/3 )                 
( Copyright [ c ] 1991 by BDS Software )                        
16 base !                                                       
: dmax ( d1 d2 -- d3 ) 2over 2over d< if 2swap then 2drop ;     
: dmin ( d1 d2 -- d3 ) 2over 2over d< if 2drop else 2swap       
     2drop then ;                                               
create du< ( ud1 ud2 -- flag ) here dup 2- ! 3416 , AE44 ,      
     ACC4 , 250D , 2206 , AE46 , AC42 , 2505 , 8E00 ,           
     0020 , 038E , FFFF , 3706 , 3706 , 3706 , 3706 ,           
     3610 , 3516 , AEA1 , 6E91 ,                                
decimal